plugin-cisco_temp: cisco_temp

#!/usr/bin/perl -w

# Copyright 2005 - Bjorn Ruberg <bjorn@linpro.no>

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
#
#
# This plugin supports Cisco switches that supports the ciscoEnvMonMIB MIB.
# For a list of supported Cisco units and images, check the URL
# http://tools.cisco.com/Support/SNMP/do/BrowseMIB.do?local=en&step=2&mibName=CISCO-ENVMON-MIB
#
# Also see http://www.cisco.com/en/US/tech/tk648/tk362/technologies_tech_note09186a0080094b9e.shtml
# for another approach on Cisco 6500/7500 units.

#%# family=contrib
#%# capabilities=

use strict;
use Data::Dumper;
use Net::SNMP qw ( snmp_event_loop ticks_to_time );

use vars qw ( $host $community $config $response );

($host = $0) =~ s/^.*\_//
    or die ("You need to include the hostname to be queried as a part of the plugin filename, prefixed with '_'.\nExample: " . $0 . "_127.0.0.1\n\n");

# community string is defined in the Munin plugin environment file(s).
# e.g.: env.community SecretString
$community = $ENV{'community'} or die ("No SNMP community string set");

if ($ARGV[0]) {
    if ($ARGV[0] eq "config") {
        $config = 1;
    }
}

my ($session, $error) = Net::SNMP->session(
                                           -hostname  => $host,
                                           -community => $community
                                           );

my $baseoid = "1.3.6.1.4.1.9.9.13.1.3.1"; # Net::SNMP doesn't like the prefixed '.'

# .2 = definitions
# .3 = values

if ($config) {
    $baseoid .= ".2";
} else {
    $baseoid .= ".3";
}

# Fetch data
if (!defined ($response = $session->get_table ($baseoid))) {
    printf ("ERROR: %s.\n", $session->error());
    $session->close();
    exit 2;
} else {
    if ($config) {
        print "host_name $host\n";
        print "graph_args --base 1000\n";
        print "graph_title Cisco switch temperature\n";
        print "graph_category System\n";
        while (my ($key, $value) = each %$response) {
            $key =~ s/^.*\.//;
            print "temp${key}.label $value\n";
            print "temp${key}.type GAUGE\n";
            if ($value =~ /intake/i) {
                # Larger Cisco switches have intake and exhaust sensors.
                # e.g. the 6500 series
                print "temp${key}.warning 30\n";
                print "temp${key}.critical 35\n";
            } else {
                print "temp${key}.warning 35\n";
                print "temp${key}.critical 40\n";
            }
        }
    } else {
        # Business as usual
        while ( my ($key, $value) = each %$response) {
            $key =~ s/^.*\.//;
            print "temp${key}.value $value\n";
        }
    }
}